Redirecting Netflix and Youtube traffic to another gateway by IP addresses on Mikrotik router

I help a friend in taking care of the network with few buildings with appartments for rent.

During the holiday season all apartments are fully booked, and that means we have 40-60 guests. There are 18 smart TV boxes with Netflix, Youtube etc.

We have 4 internet provider connections at this moment and all of them have average stability and speed because houses are in the mountains and there are no fiber optic links and we have to use 1 radio link (not bad) and 3 LTE connections (pretty bad at holiday season because there are many tourists and hotels nearby and the LTE infrastructure sometimes cannot handle all devices properly).

I was experimenting with load balancing (multiple WAN, with packet marking), but when we had problems with LTE stability during holidays everything was not working properly, so I gave up on splitting traffic and I switched all to best gateway and I archieved best stability (but with slow speed) this way.

Now I want to set default routes to Netflix and maybe Youtube to slower/less reliable gateways, and leave the best connection for other internet connections.

I'm using relatively low cost Mikrotik router (RB760) and I want to avoid complicated configuration that would use a lot of CPU time and this is why I want to use simple routing for this task.

My question is:

Do youtube and netflix provide any IP address lists which can be used to create default routes to them through the selected gateway?

So far I have found this article regarding Netflix: link and this article for Youtube: link but I'm not sure if these addresses appropriate for the traffic control I want to achieve.

I also would like to read what you guys think about this idea in general.

I've done this, here are the steps:

1. Set your Mikrotik router as DNS server for the clients
2. Run the following script every 10 seconds or so, to find in DNS table all netflix entries, and put them in a list (address-list)
3. Set up mangle rule to mark all packets going to that list (i.e. Netflix) a particular route mark.
4. Add a route to your special tourist gateway for all packets marked as above.
5. Get a coffee

Script

:global ajouteIP do={
  :if ([:len [/ip firewall address-list find address="$nouvelleIP" and list="netflix"]] = 0) do={
    /ip firewall address-list add list="netflix" address=$nouvelleIP timeout=02:00:00
  }
}

:local myServers { "nflx";"nflximg";"unodns";"uno";"netfl"}
/ip dns cache all {
  :foreach i in=$myServers do={
    :foreach j in=[find where (name~$i)] do={
      :local myName [get $j name]
      :local myType [get $j type]
      :local myData [get $j data]
      :if ($myType = "A") do={
        $ajouteIP nouvelleIP=$myData
       }

      :if ($myType = "CNAME") do={
        :local ipResolue [:resolve "$myData"];
         $ajouteIP nouvelleIP=$ipResolue
      }
    }
  }
}

Mangle rule

/ip firewall mangle
add action=mark-routing chain=prerouting comment="Sortie Netflix" dst-address-list=netflix new-routing-mark=via-sortie-netflix passthrough=yes protocol=tcp src-address=[your clients IP addresses]

Route rule

/ip route
add distance=1 gateway=[Tourist gateway IP] routing-mark=via-sortie-netflix